飞思卡尔8位单片机MC9S0816程序08系列MCU编程器的开发程序.doc

16.3.6 针对目标芯片JB8的编程
（1）JB8的整体擦除
（2）JB8的页写入
表16-9 JB8的整体擦除子程序和页写入子程序
整体擦除
页写入
LDHX #$FFFF
LDA #$FF ;$FFàFLBPR
STA $FE09 ;整个Flash不受保护
LDA #$03
BSR Delay ;延迟
LDA #$06
STA $FE08 ;$06àFLCR
LDA $FE09 ;读FLBPR
STA ,X ;向HX写入任意值
LDA #$01
BSR Delay ;延迟Tnvs
LDA #$0E
STA $FE08 ;$0EàFLCR
LDX #$04 ;延迟Tmerase
Loop:
LDA #$F8
BSR Delay
DBNZX Loop
LDA #$0C
STA $FE08 ;$0CàFLCR
LDA #$3B
BSR Delay ;延迟Tnvhl
LDA #$00
STA $FE08 ;$00àFLCR
LDA #$00
BSR Delay ;延迟Trcv
LDA #$00 ;$00àFLBPR
STA $FE09 ;整个Flash受保护
SWI ;软中断指令
;延迟子程序,入口参数为A
Delay:
NOP ;1个周期
NOP ;1个周期
DBNZA Delay ;3个周期
RTS ;4个周期

LDA #$FF
STA $FE09
LDA #$03
BSR delay
LDA #$01 ;(1)
STA $FE08
LDA $FE09 ;(2)
LDHX $00A0 ;(3)
STA ,X
LDA #$01 ;(4)delay Tnvs=6us
BSR delay
LDA #$09 ;(5)
STA $FE08
LDA #$03 ;(6)delay Tpgs=10us
BSR delay
MOV #$00,$00A0
MOV #$A3,$00A1
WriteLoop:
PSHH
PSHX
LDHX $00A0
LDA ,X ;DATA-->A
AIX #$01
STHX $00A0 ;X-->($00A0)
PULX
PULH
STA ,X ;A-->FLASH(HX)
LDA #$09 ;(8)delay Tprog=22us
BSR delay
AIX #$01 ;FLASHaddr+1
DBNZ $00A2,WriteLoop ;
LDA #$08 ;(10)
STA $FE08
LDA #$01 ;(11)delay Tnvh=6us
BSR delay
LDA #$00 ;(12)
STA $FE08
LDA #$00 ;(13)delay Trcv=4us
BSR delay
LDA #$00
STA $FE09
SWI
delay:
NOP
NOP
DBNZA delay
RTS
16.3.7 基板中主控MCU的编程
（1）主流程
（2）整体擦除目标MCU子程序
用监控命令WRITE和IWRITE将16.3.6中的整体擦除JB8的67字节代码写到目标芯片JB8的RAM中，然后发送RUN命令执行之，整体擦除的梦想就实现了。
*SendNBytesToR-------------*
*功能:向JB8内存发送N个Bytes
*入口:A:数据个数
* HX:N个数据在GP中的起始位置
* AddrH\AddrL 写入地址的高\低字节
*占用寄存器:A、HX
*内部调用:Write1Byte、IWrite1Byte
***************************************
SendNBytesToR:
PSHA ;A中存放数据个数
LDA ,X
JSR Write1Byte
SendNBytesTOR1:
PULA
DECA
BEQ SendNExit
PSHA
AIX #$1
LDA ,X
JSR IWrite1Byte
BRA SendNBytesTOR1
SendNExit:
RTS
*EraseTargetFlash:
*功能：整体擦除目标FLASH
*①发送整体擦除程序
*②运行整体擦除程序
*-------------------------*
EraseTargetFlash:
;=========写EraseProgram======
LDHX # EraseAll
MOV #$00,AddrH
MOV #$41,AddrL
LDA #!67
JSR SendNBytesToR
;=========RUN EraseProgram=====
LDHX #$0041
JSR RunProgram
RTS

表16-10 主控MCU中整体擦除目标FLASH的源码

接收PC机发来的总页数PageNum
PageNum=0?
返回
是
否
图16-11写目标MCU子程序流程图
将页写入子程序的二进制代码送往JB8的$41开始的内存区
接收PC机发来的页数据内容，暂存于PageBuffer中
将页数据内容发送到JB8的$A0开始的内存区
发送运行监控命令RUN，写入当前页
PageNum减1
（3）写目标MCU子程序
写目标MCU子程序可以分为以下几步来实现：
① 用监控命令WRITE和IWRITE将16.3.6中页写入程序的89字节代码写到目标芯片JB8的$0041开始的RAM区域中。
② 接收PC的写入的总页数。
③ 接收PC的页数据内容(包含页首址和数据个数)
④ 将页数据内容用监控命令WRITE和IWRITE写入JB8的RAM中从$00A0开始的地址空间中。
⑤ 发送运行监控命令RUN，写入一页。
⑥ 判断是否还有需要写入的页，如果有，则转第③步，直到写入所有的页。
从以上的写入过程来看，在写入过程中，要多次执行页写入程序，而在实际中，只需要传送一次页写入程序，以后的写入过程只需要传入需要写入的数据。写入过程的流程图如图16-11所示。源码见表16-11。
*ReceiveOnePage---------
*功能：从计算机中接收一页数据
*入口：HX
*出口：Data~{Data+DataNum}
*------------------------*
ReceiveOnePage:
BRCLR 5,SCS1,ReceiveOnePage
LDA SCDR
STA DataNum ;DataNumà页数据个数
ReceiveData:
BRCLR 5,SCS1,ReceiveData
LDA SCDR
STA ,X ;放入内存{Data+X}中
AIX #$1
DBNZ DataNum,ReceiveData
RTS
;=======================================
*WriteOnePage-----------*
*功能：将起始地址、页数据个数、页数据
* 移入JB8的Ram中,运行写入程序
*入口：HX为起始内存单元地址的连续N个字节
* 第1字节为数据个数+3，后面字节
* 依次为：高地址、低地址、数据个数、数据
*占用内存:DataNum
*---------------------------------
WriteOnePage:
LDA ,X
STA DataNum
;=========写数据到内存===============
AIX #$1
Mov #$00,AddrH
MOV #$A0,AddrL
LDA DataNum
JSR SendNBytesToR
;=============执行程序=========
LDHX #$0041
JSR RunProgram
RTS
* WriteTargetFlash
*功能：向JB8的FLASH中写入一个S19文件
*①发送写入程序
*②接收总页码
*③发送88àPC，表示可以接收下一页数据
*④接收PC的页数据内容并发送到JB8内存
*⑤写入一页
*⑥总页码减1，不为0转③
*------------------------------------*
WriteTargetFlash:
JSR SendWriteProg
BRCLR 5,SCS1,*
LDA SCDR
STA PageNum
ReceiveNextPage:
LDA #!88
BRCLR 7,SCS1,*
STA SCDR
LDHX #PageData
JSR ReceiveOnePage
LDHX #PageData
JSR WriteOnePage
DEC PageNum ;PageNum-1=0则Z=1
BNE ReceiveNextPage ;Z=0转移
RTS
;==============================
SendWriteProg:
LDHX #WriteP
Mov #$00,AddrH
MOV #$41,AddrL
LDA #!89
JSR SendNBytesToR
RTS
;==============================
表16-11 S19文件写入目标FLASH的源码

16.4 HCS08系列MCU编程器原理
16.4.3 数据通信格式
如果用GP32作为主机，根据图16-20的时序，可以编写相应的发送1位数据的子程序，源码如表16-13所示。
表16-13 主机向目标MCUGB60发送1位数据子程序
发送位数据1子程序
发送位数据0子程序
*SendOneBitH
*----发送1Bit高电平子程序-----*
*功能：
*GP32通过PTA3向GB60发送1位1的数据
*说明：(1)GP32 5个周期低电平
* 相当于GT60的4个低电平
* GP32->4.9MHZ GT60->4MHZ)
* (2)后续12个周期的高电平状态
* (3)将GP32的PTA3置高
*------------------------------*
SendOneBitH:
BSET 3,DDRA
BCLR 3,PTA
NOP
BSET 3,PTA
NOP ;延时10 NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
BSET 3,DDRA
BSET 3,PTA
RTS
*SendOneBitL
*----发送1Bit低电平子程序-----*
*功能：
*GP32通过PTA3向GB60发送1位0的数据
*说明：(1)GP32 5个周期低电平
* 相当于GT60的4个低电平
* GP32->4.9MHZ GT60->4MHZ)
* (2)后续12个周期的低电平状态
* (3)将GP32的PTA3置高
*------------------------------*
SendOneBitL:
BSET 3,DDRA
BCLR 3,PTA
NOP
NOP
NOP
NOP
NOP ;延时12 NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
BSET 3,DDRA ;结束该位
BSET 3,PTA
RTS

GP32主机接收目标MCU一位信号的源代码如表16-14所示。
表16-14 主机GP32接收目标MCUG B60发送的1位数据子程序
* Receive1Bit *
*----接收1Bit子程序 *
*功能：主机GP32接收目标MCUG B60发送的1位数据-----*
*说明：(1) GP32向GB60发送2C的低电平 *
* (2) 延时10C 后读取信息àC *
*出口：C 接收的一位信息 *
*-------------------------------------------------------------------------------*
Receive1Bit:
;(1)GP32向GB60发送2C的低电平
BSET 3,DDRA
BCLR 3,PTA
NOP
BSET 3,PTA
;(2)延时10C 后读取信息
BCLR 3,DDRA
BRSET 3,PTA,CtoA
CToA:
ROLA ;C-->A的最低位 ;1C
BSET 3,DDRA
RTS