定量定性资料SAS上机实习.doc

统计分析与SAS实现上机实习题
一、定量资料上机实习题
要求：
（1） 先判断定量资料所对应的实验设计类型；
（2） 假定资料满足参数检验的前提条件，请选用相应设计的定量资料的方差分析，并用SAS软件实现统计计算；
（3） 摘录主要计算结果并合理解释，给出统计学结论和专业结论。

【练习1】取4窝不同种系未成年的大白鼠，每窝3只，随机分配到三个实验组中，分别注射不同剂量雌激素，经过一定时间后处死大白鼠测子宫重量，资料见表1。问剂量和窝别的各自水平下子宫重量之间的差别有无统计学意义？若剂量间差别有统计学意义，请作两两比较。

表1 未成年大白鼠注射不同剂量雌激素后的子宫重量
窝别
子宫重量(g)
剂量(μg/100g):0.2
0.4
0.8
合计
1

106
116
145
367
2

42
68
115
225
3

70
111
133
314
4

42
63
87
192
合计

260
358
480
1098
定量资料的随机区组设计（区组因素：窝别；实验因素：剂量）
【SAS程序】：
DATA PGM15G;
DO A=1 TO 4; /*A为窝别*/
DO B=1 TO 3; /*B为雌激素剂量*/
INPUT X @@; /*X为子宫重量*/
OUTPUT;
END;
END;
CARDS;
106 116 145
42 68 115
70 111 133
42 63 87
;
RUN;
ods html; /*将结果输出成网页格式，SAS9.0以后版本可用*/
PROC GLM DATA=PGM15G;
CLASS A B;
MODEL X=A B / SS3;
MEANS A B; /*给出因素A、B各水平下的均值和标准差*/
MEANS B / SNK; /*对因素B（即剂量）各水平下的均值进行两两比较*/
RUN;
ODS HTML CLOSE;

【练习2】一位工程师研究由钻头压力产生的冲力。考察了A（钻孔速度）和B（进料速度），两因素分别取2与3水平，各水平组合下均做了两次独立重复实验，资料见表2。假定资料满足参数检验的前提条件，且两因素对观测结果的影响地位平等，已知冲力越小越好，试作分析，尽可能给出较为明确的统计和专业结论。
表2 在钻孔速度和进料速度取不同水平的条件下冲力的测定结果

钻 孔 冲力（单位）
速 度 进料速度：0.015 0.030 0.045

125 2.70 2.45 2.60
2.78 2.49 2.72
200 2.83 2.85 2.86
2.86 2.80 2.87

两因素2 x 3析因设计
【SAS程序】：
DATA aaa;
DO zs=125,200;
DO repeat=1 TO 2; /*每种试验条件下有2次独立重复试验*/
do js=0.015,0.030,0.045;
INPUT cl @@;
OUTPUT;
END;
END;
END;
CARDS;
2.70 2.45 2.60
2.78 2.49 2.72
2.83 2.85 2.86
2.86 2.80 2.87
;
run;
ods html;
PROC GLM;
CLASS zs js;
MODEL cl=zs js zs*js / SS3;
MEANS zs*js;
LSMEANS zs*js / TDIFF PDIFF; /*对 zs和js各水平组合而成的试验条件进行均数进行两两比较*/
RUN;
ods html close;

二、定性资料上机实习题
要求：
（1）若题目中未给出表格，请列出标准的列联表，并对其命名；
（2）若题目中已列出不规范的表格，先修改，然后对其命名；
（3）根据分析目的或自己提出分析目的、资料的前提条件选用相应的统计分析方法，并用SAS软件实现计算；
（4）将主要计算结果摘录出来，给出统计学和专业结论。

【练习1】某卫生防疫站对屠宰场及肉食零售点的猪肉,检查其表层沙门氏菌带菌情况，结果如下表。试比较屠宰场与肉食零售点猪肉表层沙门氏菌的带菌率之间差别有无统计学意义?
表1 屠宰场及肉食零售点猪肉表层沙门氏菌抽检结果
采样地点
例数
带菌率(%)
阳性数值
阴性数值
屠宰场
2
26
7.14
零售点
8
21
27.59
横断面研究设计
【SAS程序】：
DATA PGM19A;
DO A=1 TO 2;
DO B=1 TO 2;
INPUT F @@;
OUTPUT;
END;
END;
CARDS;
2 26
8 21
;
run;
ods html;
PROC FREQ;
WEIGHT F;
TABLES A*B / CHISQ;
RUN;
ods html close;

【练习2】有人对某部门22707名雇员中，普查了HBsAg,其中3454名阳性，19253名为阴性。从1975年起，追踪了3年，发现在阳性组有40名患了肝癌，阴性组仅一名患肝癌。试选用合适的方法对资料进行全面分析。
队列研究设计2 x 2表
【SAS程序】：
DATA PGM19B;
DO A=1 TO 2;
DO B=1 TO 2;
INPUT F @@;
OUTPUT;
END;
END;
CARDS;
40 3414
1 19252
;
run;
ods html;
PROC FREQ;
WEIGHT F;
TABLES A*B / CHISQ cmh;
RUN;
ods html close;

【练习3】APOE-4等位基因与老年痴呆性的关联研究：以600名晚发及散发老年痴呆患者和400名正常对照为研究对象，分析APOE-4等位基因与老年痴呆性的关系。

表4 APOE-4等位基因与老年痴呆性病例对照关联研究
AGT等位基因
例数
合计
病例组
对照组
APOE-4
240
60
300
非APOE-4
360
340
700
合计
600
400
1000
病例对照研究设计2 x 2表

【SAS程序】：
ATA PGM20;
DO A=1 TO 2;
DO B=1 TO 2;
INPUT F @@;
OUTPUT;
END;
END;
CARDS;
240 60
360 340
;
run;
ods html;
PROC FREQ;
WEIGHT F;
TABLES A*B / CHISQ cmh;
RUN;
ods html close;

【练习4】请分析下表资料。已从专业上认定培养的阳性结果就是“真阳性”，而不会出现假阳性。
表3 两种培养基对同一批痰液标本同时培养的结果
甲培养基
培养结果

例数

乙培养基结果：
+
-
合计
+

36
34
70
-

0
135
135
合计

36
169
205
隐含金标准配对设计2 x 2表
配对设计2×2列联表资料总体率差异性检验统计量的计算公式
若b+c≥40时

若b+c＜40时

【SAS程序】：
DATA PGM19F;
INPUT b c;
chi=(ABS(b-c)-1)**2/(b+c);
p=1-PROBCHI(chi,1);
chi=ROUND(chi, 0.001);
IF p>0.0001 THEN p=ROUND(p,0.0001);
FILE PRINT;
PUT #2 @10 'Chisq' @30 'P value'
#4 @10 chi @30 p;
CARDS;
34 0
;
run;
（甲培养基的阳性数大于乙培养基的阳性数）

【练习5】请分析下表资料。
表6 两法检查室壁收缩运动的符合情况
━━━━━━━━━━━━━━━━━━━
对比法测 冠心病人数
定的结果核素法∶正常 减弱 异常
───────────────────
正 常 58 2 3
减 弱 1 42 7
异 常 8 9 17
───────────────
合计 67 53 27
━━━━━━━━━━━━━━━━━━━
双向有序且属性相同R x C列联表（Kappa检验）
【SAS程序】：
data aaa;
do a=1 to 3;
do b=1 to 3;
input f @@;
output;
end;
end;
cards;
58 2 3
1 42 7
8 9 17
;
run;
ods html;

*简单kappa检验;
proc freq data=aaa;
weight f;
tables a*b;
test kappa;
run;

*加权kappa检验;
proc freq;
weight f;
tables a*b;
test wtkap;
run;
ods html close;
（两种方法的一致性检测有统计学意义）
简单kappa检验和加权kappa检验这两种方法都是用来检验两种评价方法是否具有一致性的方法。其主要的区别是两种方法计算的公式不一样，更具体地说是对两个变量的打分不一样，简单kappa检验主要是利用对角线上的信息，加权kappa检验除了利用对角线上的数据外，还将对角线外的数据进行加权打分，将对角线外的信息也充分利用。所以在选择方法时应根据专业知识，如果两个变量取值的界线比较明确，如“+”“++”“+++”等，这时可以选用简单的kappa检验，如果两个变量的取值不十分明确，人为的因素较多时，就可选用加权kappa检验。

【练习6】请分析下表资料。
表5 某地6094人按2种血型系统划分的结果
━━━━━━━━━━━━━━━━━━━
ABO 人 数
血型 MN血型:M N MN
───────────────────
O 431 490 902
A 388 410 800
B 495 587 950
AB 137 179 325
───────────────
合计 1451 1666 2977
━━━━━━━━━━━━━━━━━━━
双向无序R x C列联表（卡方或Fisher精确检验）
【自由度=（行数-1）X（列数-1】
【SAS程序】：
DATA PGM20A;
DO A=1 TO 4;
DO B=1 TO 3;
INPUT F @@;
OUTPUT;
END;
END;
CARDS;
431 490 902
388 410 800
495 587 950
137 179 325
;
run;
ods html;

PROC FREQ;
WEIGHT F;
TABLES A*B / CHISQ;*exact;
RUN;
ods html close;
（行变量与列变量相互独立，……）
分析方法选择
不超过1/5的格子理论频数<5时，此类资料应采用检验处理。
其他情形，可采用Fisher精确检验处理。

【练习7】请分析下表资料。
表7 3种药物疗效的观察结果
━━━━━━━━━━━━━━━━━━━
疗 人 数
效 药物∶ A B C
───────────────────
治愈 15 4 1
显效 49 9 15
好转 31 50 45
无效 5 22 24
───────────────
合计 100 85 85
━━━━━━━━━━━━━━━━━━━
结果变量为有序变量的单向有序R x C列联表
【SAS程序】：
*方法1;
DATA PGM20C;
DO A=1 TO 4;
DO B=1 TO 3;
INPUT F @@;
OUTPUT;
END;
END;
CARDS;
15 4 1
49 9 15
31 50 45
5 22 24
;
run;
ods html;

PROC NPAR1WAY WILCOXON;
FREQ F;
CLASS B;
VAR A;
RUN;

*方法2;
proc freq data=PGM20C;
weight f;
tables b*a/cmh scores=rank;
run;
ods html close;

【练习8】请分析下表资料。
表8 眼晶状体混浊度与年龄之关系
━━━━━━━━━━━━━━━━━━━
晶状体混 眼 数
浊 程度 年龄∶20～ 30～ 40～
───────────────────
＋ 215 131 148
++ 67 101 128
+++ 44 63 132
───────────────
合计 326 295 408
━━━━━━━━━━━━━━━━━━━
双向有序且属性不同R x C列联表 （spearman秩相关）
【SAS程序】：
DATA PGM20E;
DO A=1 TO 3;
DO B=1 TO 3;
INPUT F @@;
OUTPUT;
END;
END;
CARDS;
215 131 148
67 101 128
44 63 132
;
run;
ods html;
PROC CORR SPEARMAN;
VAR A B;
FREQ F;
RUN;
ods html close;