公众号转发想欧奈尔一样思索指标和公式.docx

公众号转发。想欧奈尔一样思索指标和公式
指标和选股公式
像欧奈尔一样思索 8月11日
1.口袋支点
MA50:=MA(C,10);
MA150:=MA(C,50);
MA200:=MA(C,120);
MA22:=REF(MA200,20); 
L250:=LLV(LOW,250);
H250:=HHV(HIGH,250);
X:=IF(C<REF(C,1),V,0);
口袋支点:(C>O AND V>REF(HHV(X,10),1)) AND (MA200>MA22 AND C>MA50 AND C>MA150 AND C>MA200 AND MA50>MA150 AND MA50>MA200 AND C>L250*1.3 AND  C>H250*0.9 ); 
2.净利润断层（刷新财务数据后业绩断显示十字星，也可选股)
高开缺口 := LOW>REF(HIGH,1) OR CLOSE/REF(CLOSE,1)>1.08;
{高开缺口 := LOW>REF(HIGH,1);}
当前日期 := DATE-1000000;
SV := -1;
EV := IF(WEEKDAY=1,3,2);
{业绩预告}
预告下限 := FINVALUE(285);
预告上限 := FINVALUE(286);
预告中值 := (预告上限+预告下限)/2;
预告日期 := FINVALUE(313);
预告日期差 := (当前日期-预告日期>SV) AND (当前日期-预告日期<EV);
预告断层 := (预告中值>0) AND 高开缺口 AND 预告日期差;
{业绩快报}
快报净利润 := FINVALUE(287);
快报日期 := FINVALUE(315);
快报日期差 := (当前日期-快报日期>SV) AND (当前日期-快报日期<EV);
快报断层 := (快报净利润>0) AND 高开缺口 AND 快报日期差;
{财报}
财报净利润 := FINVALUE(95);
EPSRATE := FINVALUE(184);
财报日期 := FINVALUE(314);
财报日期差 := (当前日期-财报日期>SV) AND (当前日期-财报日期<EV);
财报断层 := 财报净利润 > 0 AND EPSRATE  > 0 AND 高开缺口 AND 财报日期差;
{最近日期断层}
最近日期断层 := 预告断层 OR 快报断层 OR 财报断层;
{指定日期1}
指定日期1 := 1;
{指定日期1业绩预告}
指预告上限1 := FINONE(285,0,指定日期1);
指预告下限1 := FINONE(286,0,指定日期1);
指预告中值1 := (指预告上限1+指预告下限1)/2;
指预告日期1 := FINONE(313,0,指定日期1);
指预告日期差1 := (当前日期-指预告日期1>SV) AND (当前日期-指预告日期1<EV);
指预告断层1 := (指预告中值1>0) AND 高开缺口 AND 指预告日期差1;
{指定日期1业绩快报}
指快报净利润1 := FINONE(287,0,指定日期1);
指快报日期1 := FINONE(315,0,指定日期1);
指快报日期差1 := (当前日期-指快报日期1>SV) AND (当前日期-指快报日期1<EV);
指快报断层1 := (指快报净利润1>0) AND 高开缺口 AND 指快报日期差1;
{指定日期1财报}
指财报净利润1 := FINONE(95,0,指定日期1);
指EPSRATE1 := FINONE(184,0,指定日期1);
指财报日期1 := FINONE(314,0,指定日期1);
指财报日期差1 := (当前日期-指财报日期1>SV) AND (当前日期-指财报日期1<EV);
指财报断层1 := 指财报净利润1 > 0 AND 指EPSRATE1  > 0 AND 高开缺口 AND 指财报日期差1;
{指定日期1断层}
指定日期1断层 := 指预告断层1 OR 指快报断层1 OR 指财报断层1;
{指定日期2}
指定日期2 := 2;
{指定日期2业绩预告}
指预告上限2 := FINONE(285,0,指定日期2);
指预告下限2 := FINONE(286,0,指定日期2);
指预告中值2 := (指预告上限2+指预告下限2)/2;
指预告日期2 := FINONE(313,0,指定日期2);
指预告日期差2 := (当前日期-指预告日期2>SV) AND (当前日期-指预告日期2<EV);
指预告断层2 := (指预告中值2>0) AND 高开缺口 AND 指预告日期差2;
{指定日期2业绩快报}
指快报净利润2 := FINONE(287,0,指定日期2);
指快报日期2 := FINONE(315,0,指定日期2);
指快报日期差2 := (当前日期-指快报日期2>SV) AND (当前日期-指快报日期2<EV);
指快报断层2 := (指快报净利润2>0) AND 高开缺口 AND 指快报日期差2;
{指定日期2财报}
指财报净利润2 := FINONE(95,0,指定日期2);
指EPSRATE2 := FINONE(184,0,指定日期2);
指财报日期2 := FINONE(314,0,指定日期2);
指财报日期差2 := (当前日期-指财报日期2>SV) AND (当前日期-指财报日期2<EV);
指财报断层2 := 指财报净利润2 > 0 AND 指EPSRATE2  > 0 AND 高开缺口 AND 指财报日期差2;
{指定日期2断层}
指定日期2断层 := 指预告断层2 OR 指快报断层2 OR 指财报断层2;
{指定日期3}
指定日期3 := 3;
{指定日期3业绩预告}
指预告上限3 := FINONE(285,0,指定日期3);
指预告下限3 := FINONE(286,0,指定日期3);
指预告中值3 := (指预告上限3+指预告下限3)/2;
指预告日期3 := FINONE(313,0,指定日期3);
指预告日期差3 := (当前日期-指预告日期3>SV) AND (当前日期-指预告日期3<EV);
指预告断层3 := (指预告中值3>0) AND 高开缺口 AND 指预告日期差3;
{指定日期3业绩快报}
指快报净利润3 := FINONE(287,0,指定日期3);
指快报日期3 := FINONE(315,0,指定日期3);
指快报日期差3 := (当前日期-指快报日期3>SV) AND (当前日期-指快报日期3<EV);
指快报断层3 := (指快报净利润3>0) AND 高开缺口 AND 指快报日期差3;
{指定日期3财报}
指财报净利润3 := FINONE(95,0,指定日期3);
指EPSRATE3 := FINONE(184,0,指定日期3);
指财报日期3 := FINONE(314,0,指定日期3);
指财报日期差3 := (当前日期-指财报日期3>SV) AND (当前日期-指财报日期3<EV);
指财报断层3 := 指财报净利润3 > 0 AND 指EPSRATE3  > 0 AND 高开缺口 AND 指财报日期差3;
{指定日期3断层}
指定日期3断层 := 指预告断层3 OR 指快报断层3 OR 指财报断层3;
{指定日期4}
指定日期4 := 4;
{指定日期4业绩预告}
指预告上限4 := FINONE(285,0,指定日期4);
指预告下限4 := FINONE(286,0,指定日期4);
指预告中值4 := (指预告上限4+指预告下限4)/2;
指预告日期4 := FINONE(313,0,指定日期4);
指预告日期差4 := (当前日期-指预告日期4>SV) AND (当前日期-指预告日期4<EV);
指预告断层4 := (指预告中值4>0) AND 高开缺口 AND 指预告日期差4;
{指定日期4业绩快报}
指快报净利润4 := FINONE(287,0,指定日期4);
指快报日期4 := FINONE(315,0,指定日期4);
指快报日期差4 := (当前日期-指快报日期4>SV) AND (当前日期-指快报日期4<EV);
指快报断层4 := (指快报净利润4>0) AND 高开缺口 AND 指快报日期差4;
{指定日期4财报}
指财报净利润4 := FINONE(95,0,指定日期4);
指EPSRATE4 := FINONE(184,0,指定日期4);
指财报日期4 := FINONE(314,0,指定日期4);
指财报日期差4 := (当前日期-指财报日期4>SV) AND (当前日期-指财报日期4<EV);
指财报断层4 := 指财报净利润4 > 0 AND 指EPSRATE4  > 0 AND 高开缺口 AND 指财报日期差4;
{指定日期4断层}
指定日期4断层 := 指预告断层4 OR 指快报断层4 OR 指财报断层4;
净利润断层 := 最近日期断层 OR 指定日期1断层 OR 指定日期2断层 OR 指定日期3断层 OR 指定日期4断层;
DRAWICON(BARSSINCEN(净利润断层,5)=0,L,23);{画十字 };
3。RPS120大于87
Z:=EXTDATA_USER(1,0);{120天的}
RPS120:=Z/10;
IF(RPS120>=87,1,0);{RPS120大于87};
4. RPS50/120/250都大于87
X:=EXTDATA_USER(1,0);{120天的}
RPS120:=X/10;
Y:=EXTDATA_USER(2,0);{250天的}
RPS250:=Y/10;
Z:=EXTDATA_USER(3,0);{50天的}
RPS50:=Z/10;
A:= RPS120>87;
B:= RPS250>87;
D:= RPS50>87;
XG: A AND B AND D;
5.RPS50/120/250任意两个大于87
X:=EXTDATA_USER(1,0);{120天的}
RPS120:=X/10;
Y:=EXTDATA_USER(2,0);{250天的}
RPS250:=Y/10;
Z:=EXTDATA_USER(3,0);{50天的}
RPS50:=Z/10;
A:= RPS120>87；
B:= RPS250>87;
D:= RPS50>87;
XG:  A AND B OR A AND D  OR  B AND D;
6。接近一年新高
CLOSE/HHV(HIGH,250)>0.9;
7.港资持股
NOTEXT曲线:
GPJYVALUE(6,1,1),COLORFFFF00;
IF((GPJYVALUE(6,1,1)/FINANCE(7))>0.01,NOTEXT曲线,DRAWNULL),LINETHICK1,COLORRED;
IF((GPJYVALUE(6,1,1)/FINANCE(7))=0,NOTEXT曲线,DRAWNULL),LINETHICK1,COLORWHITE;
IF((GPJYVALUE(6,1,1)/FINANCE(7))>0 AND (GPJYVALUE(6,1,1)/FINANCE(7))<0.01,NOTEXT曲线,DRAWNULL),LINETHICK1,COLORCYAN;
持股量:GPJYVALUE(6,1,1)/10000,COLORLIBLUE;
万股:DRAWNULL;
占流通比:(GPJYVALUE(6,1,1)/FINANCE(7))*100,NODRAW;
占总股比:(GPJYVALUE(6,1,1)/FINANCE(1))*100,NODRAW;
增减万股:(GPJYVALUE(6,1,1)-REF(GPJYVALUE(6,1,1),1))/10000;
增减:=GPJYVALUE(6,1,1)-REF(GPJYVALUE(6,1,1),1);
IF(增减<0,增减,DRAWNULL),STICK,LINETHICK4,COLORCYAN;
IF(增减=0,增减,DRAWNULL),STICK,LINETHICK4,COLORWHITE;
IF(增减>0,增减,DRAWNULL),STICK,LINETHICK4,COLORRED;
8.第二阶段股票
MA50:=MA(C,50);
MA150:=MA(C,150);
MA200:=MA(C,200);
MA22:=REF(MA200,20);
L250:=LLV(LOW,250);
H250:=HHV(HIGH,250);
Y:=EXTDATA_USER(2,0)/10;
XG:MA200>MA22 AND C>MA50 AND C>MA150 AND C>MA200 AND MA50>MA150 AND MA50>MA200 AND C>L250*1.3 AND C>H250*0.9 AND Y>90 ;
9.个股温斯坦强度
N:=120;
K:=1;
VAR1:=LLV( LOW,N);
VAR2:=HHV(HIGH , N);
SD:=100*(CLOSE-VAR1)/(VAR2-VAR1);
个股MSD:MA(SD,K),COLORWHITE;
{DRAWTEXT(CURRBARSCOUNT=1,个股MSD,' '),COLORWHITE;}
VAR3:=LLV(INDEXL,N);
VAR4:=HHV(INDEXH,N);
DP:=100*(INDEXC-VAR3)/(VAR4-VAR3);
大盘MSD:MA(DP,K),COLORYELLOW;
{DRAWTEXT(CURRBARSCOUNT=1,大盘MSD,' '),COLORYELLOW;}
弱势线:20,LINETHICK1,COLORGREEN;
强势线:80,LINETHICK1,COLORMAGENTA;
IF(个股MSD>=80,个股MSD,DRAWNULL),LINETHICK2,COLORRED;
金叉买入:(CROSS(个股MSD,大盘MSD) AND (个股MSD>10) AND  BARSLASTCOUNT(个股MSD>10)>3 )*100;
11.个股温斯坦强度翻红选股
N:=120;
K:=1;
VAR1:=LLV( LOW,N);
VAR2:=HHV(HIGH,N);
SD:=100*(CLOSE-VAR1)/(VAR2-VAR1);
个股MSD:=MA(SD,K);
VAR3:=LLV(INDEXL,N);
VAR4:=HHV(INDEXH,N);
DP:=100*(INDEXC-VAR3)/(VAR4-VAR3);
大盘MSD:=MA(DP,K);
个股MSD>80;
12 .大盘温斯坦强度
N:=120;
K:=3;
ST:=EXIST((C/REF(C,1)-1)*100>5.6,60);
VAR3:=LLV(INDEXL,N);
VAR4:=HHV(INDEXH,N);
DP:=100*(INDEXC-VAR3)/(VAR4-VAR3);
大盘MSD:MA(DP,K),COLORYELLOW;
{DRAWTEXT(CURRBARSCOUNT=1,大盘MSD,' '),COLORYELLOW;}
IF(大盘MSD>=80,大盘MSD,DRAWNULL),LINETHICK2,COLORRED;
弱势线:30,LINETHICK1,COLORGREEN;
强势线:80,LINETHICK1,COLORMAGENTA;
13.天梯（这个只作为技术指标使用，不能设为选股）
STICKLINE(C>EMA(C,13),C,O,8,1),COLORRED;
STICKLINE(C>EMA(C,13),L,O,0.9,1),COLORRED;
STICKLINE(C>EMA(C,13),H,C,0.9,1),COLORRED;
STICKLINE(C<=EMA(C,13),C,O,8,0.5),;
STICKLINE(C<=EMA(C,13),H,L,0.9,0.5),;
持股线:EMA(CLOSE,13),COLORRED,LINETHICK2;
生命线:EMA(CLOSE,25),COLORYELLOW;
A1:=EMA(C,13);
长牛线:EMA(CLOSE,235);
A2:=EMA(C,25);
A3:=(A1+A2)/2;
DRAWICON(CROSS(A1,A2),A2,1);
DRAWICON(CROSS(A2,A1),A1,2);
EMA(CLOSE,235),COLOR0099FF;
14. 捡钱10
ZZ:=EXTDATA_USER(6,0);
RPS20:=ZZ/10;
DD:=IF(RPS20<=90,0,1);
A1:=C/MA(C,250)>1;
NH1:=IF(H<HHV(H,20),0,1);
B1:=COUNT(NH1,30);
NN1:=IF(C>MA(C,250),1,0);
AA1:=COUNT(NN1,30);
AB1:=HIGH/HHV(HIGH,120)>0.9;
DRAWICON(BARSSINCEN(( A1 AND AA1>2  AND    AB1 AND  DD AND  C<MA(C,10)),30)=0,LOW,9);
15.捡钱20
ZZ:=EXTDATA_USER(3,0);
RPS50:=ZZ/10;
DD:=IF(RPS50<=90,0,1);
A1:=C/MA(C,250)>1;
NH1:=IF(H<HHV(H,20),0,1);
B1:=COUNT(NH1,30);
NN1:=IF(C>MA(C,250),1,0);
AA1:=COUNT(NN1,30);
AB1:=HIGH/HHV(HIGH,120)>0.9;
DRAWICON(BARSSINCEN(( A1 AND AA1>2  AND    AB1 AND  DD AND   C<MA(C,20)),30)=0,LOW,9);
16.月线反转后首次口袋支点
RPS50:=EXTDATA_USER(3,0)/10;
D:=IF(RPS50<=85,0,1);
A:=C/MA(C,250)>1;
NH:=IF(H<HHV(H,50),0,1);
B:=COUNT(NH,30);
NN:=IF(C>MA(C,250),1,0);
AA:=COUNT(NN,30);
AB:=H/HHV(H,120)>0.9 ;
LXM1:=(A AND B AND D AND AA>2 AND AA<30 AND AB);
VAR1:=BARSLAST(LXM1)<=120;
MA50:=MA(C,10);
MA150:=MA(C,50);
MA200:=MA(C,120);
MA22:=REF(MA200,20); 
L250:=LLV(LOW,250);
H250:=HHV(HIGH,250);
X:=IF(C<REF(C,1),V,0);
LXM2:=(C>O AND V>REF(HHV(X,10),1)) AND (MA200>MA22 AND C>MA50 AND C>MA150 AND C>MA200 AND MA50>MA150 AND MA50>MA200 AND C>L250*1.3 AND  C>H250*0.9 ); 
VAR2:=VAR1 AND LXM2;
BARSSINCEN(VAR2,30)=0;
17.两个月线反转
Z:=EXTDATA_USER(3,0);   {50天的, 添上你自己的}
RPS50:=Z/10;
D:=IF(RPS50<=85,0,1);
A:=C/MA(C,250)>1;
NH:=IF(H<HHV(H,50),0,1);
B:=COUNT(NH,30);
NN:=IF(C>MA(C,250),1,0);
AA:=COUNT(NN,30);
AB:=HIGH/HHV(HIGH,120)>0.9;
LXM1:=BARSSINCEN((A AND B AND D AND  AA>2  AND AA<30 AND AB),30)=0;
LXM1 AND COUNT(LXM1,150)>=2 ;
18.RPS变强
X:=EXTDATA_USER(1,0);{120天的}
RPS120:=X/10;
Y:=EXTDATA_USER(2,0);{250天的}
RPS250:=Y/10;
Z:=EXTDATA_USER(3,0);{50天的}
RPS50:=Z/10;
P:=EXTDATA_USER(6,0);{20天的}
RPS20:=P/10;
RPSJQ:=(RPS50*6+RPS250*2+RPS120*2)/10;
A:=RPS50>MA(RPS50,10);
B:=RPS20>MA(RPS20,10);
D:=RPS120>MA(RPS120,20);
XG:RPS120>75 AND RPS50>85 AND RPS20>90 AND A AND B AND D;
19.个股大底部突破
VAR1:=(REF(((HHV(HIGH,120)-LLV(LOW,120))/LLV(LOW,120)),1)<=0.5 AND CLOSE>=REF(HHV(HIGH,120),0.9) AND  BARSCOUNT(CLOSE)>120);
REF(HHV(H,120),1);
REF(LLV(L,120),1);
C;
DRAWICON(VAR1,C,34);
20.个股大底部突破选股
(REF(((HHV(HIGH,144)-LLV(LOW,144))/LLV(LOW,144)),1)<=0.5 AND CLOSE>=REF(HHV(HIGH,144),0.9) AND  BARSCOUNT(CLOSE)>144);
21.行业板块RPS走强
X:=EXTDATA_USER(1,0);{120天的}
RPS120:=X/10;
Y:=EXTDATA_USER(2,0);{250天的}
RPS250:=Y/10;
Z:=EXTDATA_USER(5,0);{50天的}
RPSBK50:=Z/10;
P:=EXTDATA_USER(4,0);{20天的}
RPSBK20:=P/10;
RPSJQ:=(RPSBK20*6+RPSBK50*2)/10;
A:=RPSBK50>MA(RPSBK50,10);
B:=RPSBK20>MA(RPSBK20,10);
XG: RPSBK50>75 AND RPSBK20>90 AND A AND B ;
22.板块月线反转
Z:=EXTDATA_USER(5,0);{50天的}
RPSBK50:=Z/10;
D:=IF(RPSBK50<=85,0,1);{RPS50大于85}
A:=C/MA(C,250)>1;{站上年线}
NH:=IF(H<HHV(H,50),0,1);
B:=COUNT(NH,30);{一月内曾创50日新高}
NN:=IF(C>MA(C,250),1,0);
AA:=COUNT(NN,30);
AB:=HIGH/HHV(HIGH,120)>0.9;{最高价距离120日内的最高价不到10%}
A  AND  B  AND  D  AND  AA>2  AND  AA<30  AND  AB;{选出刚刚站上年线小于30天，大于2天的};
23.板块温斯坦强度
N:=120;
K:=1;
VAR1:=LLV( LOW,N);
VAR2:=HHV(HIGH , N);
SD:=100*(CLOSE-VAR1)/(VAR2-VAR1);
板块MSD:MA(SD,K),COLORWHITE;
{DRAWTEXT(CURRBARSCOUNT=1,板块MSD,' '),COLORWHITE;}
VAR3:=LLV(INDEXL,N);
VAR4:=HHV(INDEXH,N);
DP:=100*(INDEXC-VAR3)/(VAR4-VAR3);
IF(板块MSD>=80,板块MSD,DRAWNULL),LINETHICK2,COLORRED;
24.板块温斯坦强度翻红选股公式
N:=120;
K:=1;
VAR1:=LLV( LOW,N);
VAR2:=HHV(HIGH,N);
SD:=100*(CLOSE-VAR1)/(VAR2-VAR1);
板块MSD:=MA(SD,K);
VAR3:=LLV(INDEXL,N);
VAR4:=HHV(INDEXH,N);
DP:=100*(INDEXC-VAR3)/(VAR4-VAR3);
大盘MSD:=MA(DP,K);
板块MSD>80;