FLAC3D深基坑的开挖与支护的命令流.doc

FLAC深基坑的开挖与支护的命令流
一、实例工程
南宁地区地层属于河流阶地二元地层，广泛分布有较厚的圆砾层，国内尚无在类似地层条件下建设地铁基坑的经验，为此，可使用 FLAC3D 对基坑开挖的全过程进行三维数值模拟，在对比实测数据的基础上，总结圆砾层中地铁车站深基坑的地下连续墙水平变形及周围地表沉降变形特征。
该基坑位于大学路与明秀路交叉路口处，沿大学东路东西向布置。车站基坑长465m，标准断面宽度为20.7m，为地下两层式结构，底板埋深为 15.535m（相对地面），顶板覆土厚度大于 3m。本工程主体建筑面积 21163.6m2，主要结构形式为双柱三跨框架箱型结构。 本工程所处的大学路为南宁市东西向的主要交通枢纽，车流量大，人流密集，地面条件复杂。
基坑施工采用明挖顺作法施工，围护结构为 800mm厚地下连续墙+内撑（三道内支撑
加一道换撑）的支护体系。第一道支撑采用钢筋混凝土支撑，尺寸为800×900mm，冠梁同时作为第一道钢筋混凝土支撑的围檩。第二、三道支撑及换撑使用钢支撑并施加预加力，直径为 609mm，壁厚为 t=16mm，斜撑段采用800×1000mm钢筋砼腰梁，其余为 2×I45C钢围檩。
二、 模型建立
建模工作由两部分组成，实体模型部分，包括土体和地下连续墙；结构单元部分，包括混凝土支撑和钢支撑。
根据对称性原理，拟选取 1/2 的实际工程尺寸进行分析。考虑到实际的基坑长度将近 500m，根据以往的经验，选取全部长度的一半虽然能够得到满意的结果，但是由于中间部分的基坑基本处于同样的受力状态，这样会使大部分的计算长度变为重复的计算，降低了计算效率。根据初步计算结果和经验，最终确定的基坑尺寸为，宽度取基坑的最大宽度 24m，开挖深度 19m，基坑长度 36m。根据地勘报告，合并相似土层，模型中共划分了 7个土层。
在 FLAC3D 中，围护结构可以用衬砌单元(liner)或实体单元模拟。根据Zdravdovi的研究，在二维平面基坑模拟中，分别采用实体单元和梁单元(相当于三维模型中的衬砌单元)计算所产生的墙体变形差别小于4%，而引起地表沉降的主要原因是围护结构变形造成的地层损失，可见上述两种方法计算结果的差别可忽略不计。相比于衬砌单元(liner)，实体单元物理模型清晰，参数相对较少且容易确定，因此本例围护结构采用实体单元模拟。
模型的范围必须要足够大以覆盖基坑开挖可能影响的区域，同时又要兼顾计算效率。根据现行国家和个地方规范的要求，参考已有的研究成果，影响范围为4 倍开挖深度，整个模型的尺寸为 96×144×39（长×宽×高 m） 。为减少不必要的网格，网格划分原则为基坑附近密集，远处稀疏，模型共有节点 10890个，单元9408个。模型如图所示。

图 建立模型
命令流如下：
n
;开挖土体
gen zone brick size 12 4 10 p0 0,0,0 p1 36,0,0 p2 0,12,0 p3 0,0,19
;开挖下部土体
gen zone brick size 12 4 4 p0 0,0,-20 p1 36,0,-20 p2 0,12,-20 p3 0,0,0
group exc
;实体地连墙
gen zone brick size 12 1 10 p0 0,12,0 p1 36,12,0 p2 0,12.8,0 p3 0,12,19
gen zone brick size 12 1 4 p0 0,12,-20 p1 36,12,-20 p2 0,12.8,-20 p3 0,12,0
gen zone brick size 1 4 10 p0 -0.8,0,0 p1 0,0,0 p2 -0.8,12,0 p3 -0.8,0,19
gen zone brick size 1 4 4 p0 -0.8,0,-20 p1 0,0,-20 p2 -0.8,12,-20 p3 -0.8,0,0
gen zone brick size 1 1 10 p0 -0.8,12,0 p1 0,12,0 p2 -0.8,12.8,0 p3 -0.8,12,19
gen zone brick size 1 1 4 p0 -0.8,12,-20 p1 0,12,-20 p2 -0.8,12.8,-20 p3 -0.8,12,0
group wall range group exc not
;--------------------------------------------------------------------------------
;土体
gen zone brick size 12 5 10 p0 0,12.8,0 p1 36,12.8,0 p2 0,32,0 p3 0,12.8,19
gen zone brick size 1 5 10 p0 -0.8,12.8,0 p1 0,12.8,0 p2 -0.8,32,0 p3 -0.8,12.8,19
gen zone brick size 5 5 10 p0 -20.8,12.8,0 p1 -0.8,12.8,0 p2 -20.8,32,0 p3 -20.8,12.8,19
gen zone brick size 5 1 10 p0 -20.8,12,0 p1 -0.8,12,0 p2 -20.8,12.8,0 p3 -20.8,12,19
gen zone brick size 5 4 10 p0 -20.8,0,0 p1 -0.8,0,0 p2 -20.8,12,0 p3 -20.8,0,19
gen zone brick size 12 5 4 p0 0,12.8,-20 p1 36,12.8,-20 p2 0,32,-20 p3 0,12.8,0
gen zone brick size 1 5 4 p0 -0.8,12.8,-20 p1 0,12.8,-20 p2 -0.8,32,-20 p3 -0.8,12.8,0
gen zone brick size 5 5 4 p0 -20.8,12.8,-20 p1 -0.8,12.8,-20 p2 -20.8,32,-20 p3 -20.8,12.8,0
gen zone brick size 5 1 4 p0 -20.8,12,-20 p1 -0.8,12,-20 p2 -20.8,12.8,-20 p3 -20.8,12,0
gen zone brick size 5 4 4 p0 -20.8,0,-20 p1 -0.8,0,-20 p2 -20.8,12,-20 p3 -20.8,0,0
group nearsoil range group exc not group wall not
;---------------------------------------------------------------------------------
gen zone brick size 12 9 10 p0 0,32,0 p1 36,32,0 p2 0,92,0 p3 0,32,19
gen zone brick size 1 9 10 p0 -0.8,32,0 p1 0,32,0 p2 -0.8,92,0 p3 -0.8,32,19
gen zone brick size 5 9 10 p0 -20.8,32,0 p1 -0.8,32,0 p2 -20.8,92,0 p3 -20.8,32,19
gen zone brick size 3 9 10 p0 -60,32,0 p1 -20.8,32,0 p2 -60,92,0 p3 -60,32,19
gen zone brick size 3 5 10 p0 -60,12.8,0 p1 -20.8,12.8,0 p2 -60,32,0 p3 -60,12.8,19
gen zone brick size 3 1 10 p0 -60,12,0 p1 -20.8,12,0 p2 -60,12.8,0 p3 -60,12,19
gen zone brick size 3 4 10 p0 -60,0,0 p1 -20.8,0,0 p2 -60,12,0 p3 -60,0,19
;深部土体
gen zone brick size 12 9 4 p0 0,32,-20 p1 36,32,-20 p2 0,92,-20 p3 0,32,0
gen zone brick size 1 9 4 p0 -0.8,32,-20 p1 0,32,-20 p2 -0.8,92,-20 p3 -0.8,32,0
gen zone brick size 5 9 4 p0 -20.8,32,-20 p1 -0.8,32,-20 p2 -20.8,92,-20 p3 -20.8,32,0
gen zone brick size 3 9 4 p0 -60,32,-20 p1 -20.8,32,-20 p2 -60,92,-20 p3 -60,32,0
gen zone brick size 3 5 4 p0 -60,12.8,-20 p1 -20.8,12.8,-20 p2 -60,32,-20 p3 -60,12.8,0
gen zone brick size 3 1 4 p0 -60,12,-20 p1 -20.8,12,-20 p2 -60,12.8,-20 p3 -60,12,0
gen zone brick size 3 4 4 p0 -60,0,-20 p1 -20.8,0,-20 p2 -60,12,-20 p3 -60,0,0
group farsoil range group exc not group wall not group nearsoil not
gen merge 0.01
plot block group
;镜像对称
gen zone ref nor 0 -1 0
;显示坐标轴
plot add axes red
;边界条件-------------------------------------------------------------------------
fix x range x -60.1 -59.9
fix x range x 35.9 36.1
fix y range y 91.9 92.1
fix y range y -91.9 -92.1
fix z range z -20.1 -19.9
;重力-----------------------------------------------------------------------------
set grav 0 0 -9.81
;土体材料属性----------------------------------------------------------------------
model mohr
;填土
pro bulk 6e6 she 2.22e6 fric 9 coh 20000 dens 1850 range z 16.9 19.1
;淤泥质土
pro bulk 3e6 she 1.07e6 fric 4 coh 5000 dens 1830 range z 12.9 17.1
;粘土
pro bulk 12e6 she 4.62e6 fric 15 coh 27500 dens 1970 range z 10.9 13.1
;粉土
pro bulk 10e6 she 3.8e6 fric 18 coh 8000 dens 2000 range z 8.9 11.1
;中砂,粗砂,砾砂
pro bulk 25e6 she 9.68e6 fric 30 coh 0 dens 2050 range z 2.9 9.1
;圆砾层
pro bulk 32e6 she 12.8e6 fric 32 coh 0 dens 2200 range z -4.1 3.1
;泥岩
pro bulk 50e6 she 22.5e6 fric 70 coh 0 dens 2200 range z -21.1 -3.9
;给地连墙赋本构，属性------------------------------
m e range group wall
ini density 2500 range group wall
pro young 40e9 poisson 0.167 range group wall
;计算初始平衡
plot set rotation 20 0 30
set mech ratio 1e-4
plot con szz
Solve
Save inidis0.sav ;保存初始平衡，后面再调用
通过上述命令流可得如下图所示：

图 初始平衡应力
三、 开挖与支护
该工程分四次开挖，架设三道支撑（第一道为钢筋混凝土支撑，第二、三道为钢支撑），故把工程分成四个工况。
第一工况：开挖0.5m；
第二工况：开挖6.7m，架设第一道支撑；
第三工况：开挖11.8m，架设第二道支撑；
第四工况：开挖至坑底（19m），架设第三道支撑。
命令流如下：
①工况一命令流：
restore inidis0.sav ;恢复前面的初始平衡
;速度、位移、塑性区归零 ;开挖前将其清零
initial xdisplacement 0 ydisplacement 0 zdisplacement 0
initial xvelocity 0 yvelocity 0 zvelocity 0
initial state 0
;监测内撑轴力--------------------------------- ;因工况一未架设支撑，故前面用分号隔开
;h id 1 sel beams force Fx cid=1
;h id 2 sel beams force Fx cid=2
;h id 3 sel beams force Fx cid=3
;h id 4 sel beams force Fx cid=7
;h id 5 sel beams force Fx cid=8
;h id 6 sel beams force Fx cid=9
;监测地表沉降--------------------------------
;--------------------------------------------
h id 7 gp zdis id 7172
h id 8 gp zdis id 7523
h id 9 gp zdis id 8313
h id 10 gp zdis id 8326
h id 11 gp zdis id 8339
h id 12 gp zdis id 8352
h id 13 gp zdis id 8365
h id 14 gp zdis id 10633
h id 15 gp zdis id 10646
h id 16 gp zdis id 10659
h id 17 gp zdis id 10672
h id 18 gp zdis id 10685
h id 19 gp zdis id 10698
h id 20 gp zdis id 10711
h id 21 gp zdis id 10724
h id 22 gp zdis id 10737
;监测地连墙水平位移------------------------
;中段------------------------------------------
h id 41 gp ydis id 7172
h id 42 gp ydis id 7120
h id 43 gp ydis id 7068
h id 44 gp ydis id 7016
h id 45 gp ydis id 6964
h id 46 gp ydis id 6912
h id 47 gp ydis id 6860
h id 48 gp ydis id 6808
h id 49 gp ydis id 6756
h id 50 gp ydis id 6704
h id 51 gp ydis id 6703
h id 52 gp ydis id 7380
h id 53 gp ydis id 7328
h id 54 gp ydis id 7276
h id 55 gp ydis id 7275
;边角----------------------------------------
h id 56 gp ydis id 704
h id 57 gp ydis id 639
h id 58 gp ydis id 574
h id 59 gp ydis id 509
h id 60 gp ydis id 444
h id 61 gp ydis id 379
h id 62 gp ydis id 314
h id 63 gp ydis id 249
h id 64 gp ydis id 184
h id 65 gp ydis id 108
h id 66 gp ydis id 106
h id 67 gp ydis id 964
h id 68 gp ydis id 899
h id 69 gp ydis id 823
h id 70 gp ydis id 821
;开挖------------------------------------
;第一步开挖
model null range x 0 36 y -12 12 z 18.5 19
Solve
Save stage1.sav ;保存工况一，方便下一工况调用
运行上面命令流，得到位移云图，如下所示：

图 工况一水平位移云图
②工况二命令流：
restore stage1.sav
;第二步开挖
model null range x 0 36 y -12 12 z 12.8 18.5
;设置第一道混凝土 beam内撑-------------------------------------
;设置斜撑
sel beam begin 3,12,19 end 0,9,19
sel beam begin 6,12,19 end 0,6,19
sel beam begin 9,12,19 end 0,3,19
sel beam begin 3,-12,19 end 0,-9,19
sel beam begin 6,-12,19 end 0,-6,19
sel beam begin 9,-12,19 end 0,-3,19
;设置对撑
;对撑一------------------------------------------ ;通过结构节点建立结构单元（也可通过坐标指定建立，然后再删除节点创建新的节点）—（陈育民书P150）
sel node id=101 12 12 19
sel node id=102 15 12 19
sel node id=103 18 12 19
sel node id=104 15 6 19
sel node id=105 15 -6 19
sel node id=106 12 -12 19
sel node id=107 15 -12 19
sel node id=108 18 -12 19
sel beamsel node 101 104
sel beamsel node 102 104
sel beamsel node 103 104
sel beamsel node 104 105
sel beamsel node 106 105
sel beamsel node 107 105
sel beamsel node 108 105
sel link id 101 101 target zone
sel link id 102 102 target zone
sel link id 103 103 target zone
sel link id 104 106 target zone
sel link id 105 107 target zone
sel link id 106 108 target zone

;对撑二----------------------------------------
sel node id=109 21 12 19
sel node id=110 24 12 19
sel node id=111 27 12 19
sel node id=112 24 6 19
sel node id=113 24 -6 19
sel node id=114 21 -12 19
sel node id=115 24 -12 19
sel node id=116 27 -12 19
sel beamsel node 109 112
sel beamsel node 110 112
sel beamsel node 111 112
sel beamsel node 112 113
sel beamsel node 114 113
sel beamsel node 115 113
sel beamsel node 116 113
sel link id 107 109 target zone
sel link id 108 110 target zone
sel link id 109 111 target zone
sel link id 110 114 target zone
sel link id 111 115 target zone
sel link id 112 116 target zone
;对撑三----------------------------------------
sel node id=117 30 12 19
sel node id=118 33 12 19
sel node id=119 36 12 19
sel node id=120 33 6 19
sel node id=121 33 -6 19
sel node id=122 30 -12 19
sel node id=123 33 -12 19
sel node id=124 36 -12 19
sel beamsel node 117 120
sel beamsel node 118 120
sel beamsel node 119 120
sel beamsel node 120 121
sel beamsel node 122 121
sel beamsel node 123 121
sel beamsel node 124 121
sel link id 113 117 target zone
sel link id 114 118 target zone
sel link id 115 119 target zone
sel link id 116 122 target zone
sel link id 117 123 target zone
sel link id 118 124 target zone
;内撑赋属性
Sel beam prop emod=32e9 nu=0.167
sel beam prop XCArea=7.2e-1 XCIz=4.86e-2 XCIy=3.48e-2 XCJ=0.0
;监测内撑轴力---------------------------------
h id 1 sel beams force Fx cid=1
h id 2 sel beams force Fx cid=2
h id 3 sel beams force Fx cid=3
h id 4 sel beams force Fx cid=7
h id 5 sel beams force Fx cid=8
h id 6 sel beams force Fx cid=9
;显示结构单元
plot con zdisp
plot add sel geom node off
plot add sel beam force fx
plot set rot 40 0 280
Solve
Save stage2.sav ;保存工况二，方便下一工况调用
运行上面命令流，得到位移云图，如下所示：

图 工况二水平位移云图
③工况三命令流：
restore stage2.sav
;第三步开挖
model null range x 0 36 y -12 12 z 6.2 12.8
;设置第二道钢 beam内撑-------------------------------------
;设置斜撑
sel beam begin 3,12,13.3 end 0,9,13.3
sel beam begin 6,12,13.3 end 0,6,13.3
sel beam begin 9,12,13.3 end 0,3,13.3
sel beam begin 3,-12,13.3 end 0,-9,13.3
sel beam begin 6,-12,13.3 end 0,-6,13.3
sel beam begin 9,-12,13.3 end 0,-3,13.3
;设置对撑
sel beam begin 12,12,13.3 end 12,-12,13.3
sel beam begin 15,12,13.3 end 15,-12,13.3
sel beam begin 18,12,13.3 end 18,-12,13.3
sel beam begin 21,12,13.3 end 21,-12,13.3
sel beam begin 24,12,13.3 end 24,-12,13.3
sel beam begin 27,12,13.3 end 27,-12,13.3
sel beam begin 30,12,13.3 end 30,-12,13.3
sel beam begin 33,12,13.3 end 33,-12,13.3
sel beam begin 36,12,13.3 end 36,-12,13.3
;内撑赋属性---------------------------------------
Sel beam prop emod=200e9 nu=0.3 range z 13.2 13.4
sel beam prop XCArea=3.05e-3 XCIz=1.31e-3 XCIy=1.31e-3 XCJ=0.0 range z 13.2 13.4
;显示结构单元
plot con zdisp
plot add sel geom node off
plot add sel beam force fx
plot set rot 40 0 280
Solve
Save stage3.sav ;保存工况三，方便下一工况调用
运行上面命令流，得到位移云图，如下所示：

图 工况三水平位移云图
④工况四命令流：
restore stage3.sav
;第四步开挖
model null range x 0 36 y -12 12 z 0 6.2
;设置第三道钢 beam内撑-------------------------------------
;设置斜撑
sel beam begin 3,12,6.7 end 0,9,6.7
sel beam begin 6,12,6.7 end 0,6,6.7
sel beam begin 9,12,6.7 end 0,3,6.7
sel beam begin 3,-12,6.7 end 0,-9,6.7
sel beam begin 6,-12,6.7 end 0,-6,6.7
sel beam begin 9,-12,6.7 end 0,-3,6.7
;设置对撑
sel beam begin 12,12,6.7 end 12,-12,6.7
sel beam begin 15,12,6.7 end 15,-12,6.7
sel beam begin 18,12,6.7 end 18,-12,6.7
sel beam begin 21,12,6.7 end 21,-12,6.7
sel beam begin 24,12,6.7 end 24,-12,6.7
sel beam begin 27,12,6.7 end 27,-12,6.7
sel beam begin 30,12,6.7 end 30,-12,6.7
sel beam begin 33,12,6.7 end 33,-12,6.7
sel beam begin 36,12,6.7 end 36,-12,6.7
;内撑赋属性---------------------------------------
Sel beam prop emod=200e9 nu=0.3 range z 13.2 13.4
sel beam prop XCArea=3.05e-3 XCIz=1.31e-3 XCIy=1.31e-3 XCJ=0.0 range z 13.2 13.4
;显示结构单元
plot con zdisp
plot add sel geom node off
plot add sel beam force fx
plot set rot 40 0 280
Solve
Save result.sav ;保存最后结果，通过print write n file.文件名.dat 提取数据
运行上面命令流，得到位移云图，如下所示：

图 工况三水平位移云图
四、计算结果
为了更清晰的反映计算结果，寻找内在规律，可将五个工况的地下连续墙侧移绘制在一张图中，通过Origin 作图等绘图软件。很明显，只有对数据进行更深入的处理，才能发现计算结果的规律，反映问题的本质。同时也能够让读者以最直观、最清晰的方式解读计算成果。
提取数据命令流如下：
hist write 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 file 中段水平位移.dat
hist write 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 file 边角水平位移.dat
hist write 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 file 地表沉降.dat
hist write 1 2 3 4 5 6 file 轴力.dat